***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 11, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt SS2060LHE-AU A K 
.param
+vc0 = 3.451e-7 	 vc1 = 3.893e-8  	 vc2 = 5.952e-8		 vc3 = 6.017e-2
+tc1 = 1.032e-1		 tc2 = 4.219e-2		
d1 A K diode
g1 K A value = {(vc0+vc1*v(K,A)+vc2*exp(vc3*v(K,A)))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
.model diode d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 1.317e-7            n = 0.906		  rs = 7.712e-2		 ikf = 5.897e-2
+ibv = 0.5e-3		 nbv = 1		  bv = 66
***** capacitance parameter *****
+cjo = 2.280e-10	   m = 4.549e-1		  vj = 4.007e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 0.69		 xti = 3
+trs1 = 6.910e-3 	trs2 = -0.501e-4
+tikf = -4.399e-3
.ends SS2060LHE-AU
*$
